Hollywood forums

Posted: **Mon May 27, 2019 4:44 pm**

Hello, (sorry for my bad english)

how do I know if a file is in use before erasing it?

Thank you

Posted: **Mon May 27, 2019 5:01 pm**

That's not possible and doesn't make sense in a multitasking environment. Even if there was a function called IsFileInUse() it wouldn't make sense because some other process could lock the file between your call to IsFileInUse() and the call to DeleteFile()...

Posted: **Mon May 27, 2019 11:39 pm**

For example I open picture with multiview or picshow and with my program hollywood I want to erase this picture my program will return an error and quit ... it's not very clean

Posted: **Tue May 28, 2019 10:09 am**

You can disable the internal error handler before trying to delete a file, check yourself if it failed, and enable the error handler again after that.

If you're using it often, maybe it's better to write an own delete function, like this:

Code: Select all

Function p_DeleteFile(file$)
    Local code
    ExitOnError(False)
    DeleteFile(file$)
    code = GetLastError()
    ExitOnError(True)
    If code
        DebugPrint("Error while deleting \"" .. file$ .. "\":", GetErrorName(code))
    Else
        DebugPrint("\"" .. file$ .. "\" deleted.")
    EndIf
    Return(code)
EndFunction

StringToFile("bla", "testfile")          ; Create a new file
OpenFile(1, "testfile", #MODE_READWRITE) ; Let's keep the file open
p_DeleteFile("testfile")                 ; Deleting fails, but the script continues
CloseFile(1)                             ; Let's close the file
p_DeleteFile("testfile")                 ; Deleting works now

Posted: **Tue May 28, 2019 11:58 am**

@JPV

Thank you very nice

Posted: **Tue May 28, 2019 5:49 pm**

Also note that this

Code: Select all

ExitOnError(False)
DeleteFile(file$)
code = GetLastError()
ExitOnError(True)

can be radically shortened to that now:

Code: Select all

code = ?DeleteFile(file$)

Posted: **Tue May 28, 2019 11:24 pm**

@airsoftsoftwair

Ohh good

This ? work with other function or only DeleteFile() ?

Posted: **Wed May 29, 2019 9:39 pm**

sinisrus wrote: ↑Tue May 28, 2019 11:24 pm @airsoftsoftwair
This ? work with other function or only DeleteFile() ?

Yes, it works with all functions. See here.

Hollywood forums

Control if file is used before deletefile()

Control if file is used before deletefile()

Re: Control if file is used before deletefile()

Re: Control if file is used before deletefile()

Re: Control if file is used before deletefile()

Re: Control if file is used before deletefile()

Re: Control if file is used before deletefile()

Re: Control if file is used before deletefile()

Re: Control if file is used before deletefile()